cc1 = "#5e81b5"
cc2 = "#e19c24"
cc3 = "#8fb032"
cc4 = "#eb6235"

set terminal epslatex size 8.68cm, 7.5cm standalone
set output "fig-stiffnesses.tex"

set multiplot  layout 3, 2  margins 0.185, 0.97, 0.15, 0.998  spacing 0.13, 0.015

set nokey
set xrange [-25:300]
set arrow 1 from 17.26,graph 0 to 17.26,graph 1 nohead lw 4 lc rgb cc2


set format x ""
set xtics (0, 100, 200, 300)
set ylabel '\footnotesize $\lambda / \mathrm{GPa}$' offset 3
set format y '\scriptsize $%.1f$'

set yrange [217.5:220.75]
set ytics 218,1,220
set title '\footnotesize (a) $\lambda^{(11)}_{\mathrm{A_{1\mathrm g}}}$' offset -1,-5.2
plot "data/c11pc12.dat" using 1:(100 * $2) with lines lw 3 lc rgb cc3

set ylabel ''

set yrange [306:317]
set ytics 308,2,316
set title '\footnotesize (b) $\lambda^{(22)}_{\mathrm{A_{1\mathrm g}}}$' offset -1,-5.2
plot "data/c33.dat"     using 1:(100 * $2) with lines lw 3 lc rgb cc3

set ylabel '\footnotesize $\lambda / \mathrm{GPa}$'

set yrange [112.6:114]
set ytics 112.8,0.3,113.9
set title '\footnotesize (d) $\lambda^{(12)}_{\mathrm{A_{1\mathrm g}}}$' offset -1,-5.2
plot "data/c13.dat"     using 1:(100 * $2) with lines lw 3 lc rgb cc3

set ylabel ''

set yrange [65.05:65.7]
set ytics 62.1,0.1,65.6
set title '\footnotesize (c) $\lambda^{(11)}_{\mathrm{B_{1\mathrm g}}}$' offset -1,-5.2
plot "data/c11mc12.dat" using 1:(100 * $2) with lines lw 3 lc rgb cc3

set format x '\scriptsize $%.0f$'
set ylabel '\footnotesize $\lambda / \mathrm{GPa}$'
set xlabel '\footnotesize $T / \mathrm K$'

set yrange [140:145]
set ytics 141,1,144
set title '\footnotesize (e) $\lambda^{(11)}_{\mathrm{B_{2\mathrm g}}}$' offset -1,-5.2
plot "data/c66.dat"     using 1:(100 * $2) with lines lw 3 lc rgb cc3

set ylabel ''

set yrange [101:106]
set ytics 102,1,105
set title '\footnotesize (f) $\lambda^{(11)}_{\mathrm{E_{\mathrm g}}}$' offset -1,-5.2
plot "data/c44.dat"     using 1:(100 * $2) with lines lw 3 lc rgb cc3