set terminal epslatex size 6.834, 2.81576
set output "fig_clusters_ising2d.tex"

cc1 = "#5e81b5"
cc2 = "#e19c24"
cc3 = "#8fb032"
cc4 = "#eb6235"
cc5 = "#8778b3"
cc6 = "#c56e1a"

set palette model RGB defined ( 8 cc1, 16 cc2, 32 cc3, 64 cc4, 128 cc5, 256 cc6  )

unset colorbox
set nokey
set format x '$10^{%T}$'
set logscale xy
set ylabel '$\avg{s_{\text{\sc 1c}}}L^{-\gamma/\nu}$'
set xlabel '$hL^{\beta\delta/\nu}$'

set xrange [0.000005:12000000]


set multiplot layout 2,3

set size 0.36, 0.5

dataIsing2D = "data/cluster-size/cluster-size_ising2d.dat"

set yrange [0.8:8]

unset xlabel

set label "2D Ising" at graph 0.1, 0.75

betaIsing2D = 1.0 / 8.0
nuIsing2D = 1.0
deltaIsing2D = 15.0
gammaIsing2D = 7.0 / 4.0

plot dataIsing2D using ($3/$2 * exp(log($1) * betaIsing2D * deltaIsing2D / nuIsing2D)):($4 * exp(-log($1) * gammaIsing2D / nuIsing2D)):($5 * exp(-log($1) * gammaIsing2D/nuIsing2D)):1 with yerrorbars pt 0 lw 2 palette, dataIsing2D using ($3/$2 * exp(log($1) * betaIsing2D * deltaIsing2D / nuIsing2D)):($4 * exp(-log($1) * gammaIsing2D / nuIsing2D)):1 with lines palette, 1.5 * exp(log(x) * 2 / deltaIsing2D) with lines lc black

unset label

data3Potts2D = "data/cluster-size/cluster-size_3potts2d.dat"

set xrange [0.000005:9000000]
set yrange [0.4:7]

set label "2D 3-State Potts" at graph 0.1, 0.75

unset xlabel
unset ylabel

beta3Potts2D = 1.0 / 9.0
nu3Potts2D = 5.0 / 6.0
delta3Potts2D = 14.0
gamma3Potts2D = 13.0 / 9.0

plot data3Potts2D using ($3/$2 * exp(log($1) * beta3Potts2D * delta3Potts2D / nu3Potts2D)):($4 * exp(-log($1) * gamma3Potts2D / nu3Potts2D)):($5 * exp(-log($1) * gamma3Potts2D/nu3Potts2D)):1 with yerrorbars pt 0 lw 2 palette, data3Potts2D using ($3/$2 * exp(log($1) * beta3Potts2D * delta3Potts2D / nu3Potts2D)):($4 * exp(-log($1) * gamma3Potts2D / nu3Potts2D)):1 with lines palette, 1.2 * exp(log(x) * 2 / delta3Potts2D) with lines lc black

unset label
set size 0.36, 0.5

data2Vector3D = "data/cluster-size/cluster-size_2vector3d.dat"

set xrange [0.000005:9000000]
set yrange [0.6:200]

set label "3D O(2)" at graph 0.1, 0.75

beta2Vector3D = 0.3470
nu2Vector3D = 0.6703
delta2Vector3D = 4.79539
gamma2Vector3D = 1.3169

plot data2Vector3D using ($3/$2 * exp(log($1) * beta2Vector3D * delta2Vector3D / nu2Vector3D)):($4 * exp(-log($1) * gamma2Vector3D / nu2Vector3D)):($5 * exp(-log($1) * gamma2Vector3D/nu2Vector3D)):1 with yerrorbars pt 0 lw 2 palette, data2Vector3D using ($3/$2 * exp(log($1) * beta2Vector3D * delta2Vector3D / nu2Vector3D)):($4 * exp(-log($1) * gamma2Vector3D / nu2Vector3D)):1 with lines palette, 3 * exp(log(x) * 2 / delta2Vector3D) with lines lc black

unset label

set origin -0.05,0.0
set size 0.41, 0.55

dataIsing3D = "data/cluster-size/cluster-size_ising3d.dat"

set xrange [0.000005:9000000]
set yrange [0.9:400]

set label "3D Ising" at graph 0.1, 0.75

set ylabel '$\avg{s_{\text{\sc 1c}}}L^{-\gamma/\nu}$'
set xlabel '$hL^{\beta\delta/\nu}$'

betaIsing3D = 0.326419
nuIsing3D = 0.629971
deltaIsing3D = 4.78984
gammaIsing3D = 1.237075

plot dataIsing3D using ($3/$2 * exp(log($1) * betaIsing3D * deltaIsing3D / nuIsing3D)):($4 * exp(-log($1) * gammaIsing3D / nuIsing3D)):($5 * exp(-log($1) * gammaIsing3D/nuIsing3D)):1 with yerrorbars pt 0 lw 2 palette, dataIsing3D using ($3/$2 * exp(log($1) * betaIsing3D * deltaIsing3D / nuIsing3D)):($4 * exp(-log($1) * gammaIsing3D / nuIsing3D)):1 with lines palette, 5 * exp(log(x) * 2 / deltaIsing3D) with lines lc black


unset label
unset ylabel
set size 0.333, 0.55

data4Potts2D = "data/cluster-size/cluster-size_4potts2d.dat"

set xrange [0.000005:9000000]
set yrange [0.6:4]

set label "2D 4-State Potts" at graph 0.1, 0.75

beta4Potts2D = 1.0 / 12.0
nu4Potts2D = 2.0 / 3.0
delta4Potts2D = 15.0
gamma4Potts2D = 7.0 / 6.0

plot data4Potts2D using ($3/$2 * exp(log($1) * beta4Potts2D * delta4Potts2D / nu4Potts2D)):($4 * exp(-log($1) * gamma4Potts2D / nu4Potts2D)):($5 * exp(-log($1) * gamma4Potts2D/nu4Potts2D)):1 with yerrorbars pt 0 lw 2 palette, data4Potts2D using ($3/$2 * exp(log($1) * beta4Potts2D * delta4Potts2D / nu4Potts2D)):($4 * exp(-log($1) * gamma4Potts2D / nu4Potts2D)):1 with lines palette, 1.2 * exp(log(x) * 2 / delta4Potts2D) with lines lc black

unset label
set size 0.36, 0.55

data3Vector3D = "data/cluster-size/cluster-size_3vector3d.dat"

set xrange [0.000005:9000000]
set yrange [0.6:200]

set label "3D O(3)" at graph 0.1, 0.75

beta3Vector3D = 0.3662
nu3Vector3D = 0.7073
delta3Vector3D = 4.79465
gamma3Vector3D = 1.3895

plot data3Vector3D using ($3/$2 * exp(log($1) * beta3Vector3D * delta3Vector3D / nu3Vector3D)):($4 * exp(-log($1) * gamma3Vector3D / nu3Vector3D)):($5 * exp(-log($1) * gamma3Vector3D/nu3Vector3D)):1 with yerrorbars pt 0 lw 2 palette, data3Vector3D using ($3/$2 * exp(log($1) * beta3Vector3D * delta3Vector3D / nu3Vector3D)):($4 * exp(-log($1) * gamma3Vector3D / nu3Vector3D)):1 with lines palette, 2 * exp(log(x) * 2 / delta3Vector3D) with lines lc black

unset multiplot