# data and constants, sorted by column

isingRange = "[0.0000005:5000000]"

dataIsing2D = "data/correlation-times/ising-2d.dat"
betaIsing2D = 1.0 / 8.0
nuIsing2D = 1.0
deltaIsing2D = 15.0
gammaIsing2D = 7.0 / 4.0
zIsing2D = 0.231

dataIsing3D = "data/correlation-times/ising-3d.dat"
betaIsing3D = 0.326419
nuIsing3D = 0.629971
deltaIsing3D = 4.78984
gammaIsing3D = 1.237075
zIsing3D = 0.316

pottsRange="[0.000001:5000000]"

data3Potts2D = "data/correlation-times/potts-3.dat"
beta3Potts2D = 1.0 / 9.0
nu3Potts2D = 5.0 / 6.0
delta3Potts2D = 14.0
gamma3Potts2D = 13.0 / 9.0
z3Potts2D = 0.568

data4Potts2D = "data/correlation-times/potts-4.dat"
beta4Potts2D = 1.0 / 12.0
nu4Potts2D = 2.0 / 3.0
delta4Potts2D = 15.0
gamma4Potts2D = 7.0 / 6.0
z4Potts2D = 0.953

vectorRange="[0.000001:10000000]"

data2Vector3D = "data/correlation-times/planar-pert.dat"
beta2Vector3D = 0.3470
nu2Vector3D = 0.6703
delta2Vector3D = 4.79539
gamma2Vector3D = 1.3169
z2Vector3D = 0.39

data3Vector3D = "data/correlation-times/heisenberg-pert.dat"
beta3Vector3D = 0.3662
nu3Vector3D = 0.7073
delta3Vector3D = 4.79465
gamma3Vector3D = 1.3895
z3Vector3D = 0.295

# define colors

cc1 = "#5e81b5"
cc2 = "#e19c24"
cc3 = "#8fb032"
cc4 = "#eb6235"
cc5 = "#8778b3"
cc6 = "#c56e1a"
cc7 = "#5d9ec7"

set palette model RGB defined ( 8 cc1, 16 cc2, 32 cc3, 64 cc4, 128 cc5, 256 cc6 , 512 cc7 )

# global plotting settings

set terminal epslatex size 6.834, 2.81576
set output "fig_correlation-times.tex"

set multiplot layout 2,3 margins 0.05, 0.995, 0.15, 0.99 spacing 0.05, 0.015
set size ratio 1 / 1.61803398875
set key autotitle columnhead
unset colorbox
set nokey
set logscale xy

scaledylabel = '"$\\tau\\avg{s_{\\text{\\sc 1c}}}L^{-z}$" offset 2,0'

# plotting the first row
set format x ""
unset xlabel
set ylabel @scaledylabel

# ploting Ising 2D
set xrange @isingRange
set yrange [0.2:1.1]

plot dataIsing2D using (column("H")/column("T") * exp(log(column("L")) * betaIsing2D * deltaIsing2D / nuIsing2D)):(column("t") * column("S") * exp(-log(column("L")) * (zIsing2D + 2))):(sqrt((column("dt")/column("t"))**2 + (column("dS")/column("S"))**2) * column("t") * column("S") * exp(-log(column("L")) * (zIsing2D + 2))):1 with yerrorbars pt 0 lw 2 palette,\
  dataIsing2D using (column("H")/column("T") * exp(log(column("L")) * betaIsing2D * deltaIsing2D / nuIsing2D)):(column("t") * column("S") * exp(-log(column("L")) * (zIsing2D + 2))):1 with lines palette

unset ylabel

# plotting 3 Potts 2D
set xrange @pottsRange
set yrange [0.05:2]

plot data3Potts2D using (column("H")/column("T") * exp(log(column("L")) * beta3Potts2D * delta3Potts2D / nu3Potts2D)):(column("t") * column("S") * exp(-log(column("L")) * (z3Potts2D + 2))):(sqrt((column("dt")/column("t"))**2 + (column("dS")/column("S"))**2) * column("t") * column("S") * exp(-log(column("L")) * (z3Potts2D + 2))):1 with yerrorbars pt 0 lw 2 palette,\
  data3Potts2D using (column("H")/column("T") * exp(log(column("L")) * beta3Potts2D * delta3Potts2D / nu3Potts2D)):(column("t") * column("S") * exp(-log(column("L")) * (z3Potts2D + 2))):1 with lines palette

# plotting 2 Vector 3D
set xrange @vectorRange
set yrange [0.4:2]

plot data2Vector3D using (column("H")/column("T") * exp(log(column("L")) * beta2Vector3D * delta2Vector3D / nu2Vector3D)):(column("t") * column("S") * exp(-log(column("L")) * (z2Vector3D + 3))):(sqrt((column("dt")/column("t"))**2 + (column("dS")/column("S"))**2) * column("t") * column("S") * exp(-log(column("L")) * (z2Vector3D + 3))):1 with yerrorbars pt 0 lw 2 palette,\
  data2Vector3D using (column("H")/column("T") * exp(log(column("L")) * beta2Vector3D * delta2Vector3D / nu2Vector3D)):(column("t") * column("S") * exp(-log(column("L")) * (z2Vector3D + 3))):1 with lines palette

# plotting the second row
set format x '$10^{%T}$'
set xlabel '$hL^{\beta\delta/\nu}$'
set ylabel @scaledylabel

# plotting Ising 3D
set xrange @isingRange
set yrange [0.2:1]

plot dataIsing3D using (column("H")/column("T") * exp(log(column("L")) * betaIsing3D * deltaIsing3D / nuIsing3D)):(column("t") * column("S") * exp(-log(column("L")) * (zIsing3D + 3))):(sqrt((column("dt")/column("t"))**2 + (column("dS")/column("S"))**2) * column("t") * column("S") * exp(-log(column("L")) * (zIsing3D + 3))):1 with yerrorbars pt 0 lw 2 palette,\
  dataIsing3D using (column("H")/column("T") * exp(log(column("L")) * betaIsing3D * deltaIsing3D / nuIsing3D)):(column("t") * column("S") * exp(-log(column("L")) * (zIsing3D + 3))):1 with lines palette

unset ylabel

# plotting 4 Potts 2D
set xrange @pottsRange
set yrange [0.02:4]

plot data4Potts2D using (column("H")/column("T") * exp(log(column("L")) * beta4Potts2D * delta4Potts2D / nu4Potts2D)):(column("t") * column("S") * exp(-log(column("L")) * (z4Potts2D + 2))):(sqrt((column("dt")/column("t"))**2 + (column("dS")/column("S"))**2) * column("t") * column("S") * exp(-log(column("L")) * (z4Potts2D + 2))):1 with yerrorbars pt 0 lw 2 palette,\
  data4Potts2D using (column("H")/column("T") * exp(log(column("L")) * beta4Potts2D * delta4Potts2D / nu4Potts2D)):(column("t") * column("S") * exp(-log(column("L")) * (z4Potts2D + 2))):1 with lines palette

# plotting 3 Vector 3D
set xrange @vectorRange
set yrange [0.9:4]

plot data3Vector3D using (column("H")/column("T") * exp(log(column("L")) * beta3Vector3D * delta3Vector3D / nu3Vector3D)):(column("t") * column("S") * exp(-log(column("L")) * (z3Vector3D + 3))):(sqrt((column("dt")/column("t"))**2 + (column("dS")/column("S"))**2) * column("t") * column("S") * exp(-log(column("L")) * (z3Vector3D + 3))):1 with yerrorbars pt 0 lw 2 palette,\
  data3Vector3D using (column("H")/column("T") * exp(log(column("L")) * beta3Vector3D * delta3Vector3D / nu3Vector3D)):(column("t") * column("S") * exp(-log(column("L")) * (z3Vector3D + 3))):1 with lines palette