# Maintainer: lucy <lucy@luz.lu>

pkgname=bdf-tewi-git
_gitname=tewi-font
pkgver=0.313.a975d38
pkgrel=2
pkgdesc='Bitmap font'
arch=('any')
url="https://github.com/lucy/tewi-font"
license=('MIT')
depends=('xorg-fonts-encodings' 'xorg-mkfontdir' 'xorg-mkfontscale')
makedepends=('git' 'python' 'make' 'xorg-bdftopcf' 'xorg-fonttosfnt' 'bdf2psf')
install="$pkgname.install"
source=('git+https://github.com/lucy/tewi-font.git')
sha256sums=('SKIP')

pkgver() {
  cd "$_gitname"
  echo "0.$(git rev-list --count HEAD).$(git describe --always)"
}

build() {
  cd "$_gitname"
  make var
  make all
  for file in *.bdf; do
    fonttosfnt -o out/"${file%%.bdf}.otb" "$file";
    bdf2psf --fb "$file" /usr/share/bdf2psf/standard.equivalents /usr/share/bdf2psf/ascii.set+/usr/share/bdf2psf/linux.set+/usr/share/bdf2psf/useful.set 256 out/"${file%%.bdf}.psf";
    gzip out/"${file%%.bdf}.psf"
  done
}

package() {
  cd "$_gitname"
  install -T -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  install -d -m755 "$pkgdir/usr/share/fonts/misc/"
  install -d -m755 "$pkgdir/usr/share/kbd/consolefonts/"
  install -m644 -t "$pkgdir/usr/share/fonts/misc/" out/*.pcf.gz
  install -m644 -t "$pkgdir/usr/share/fonts/misc/" out/*.otb
  install -m644 -t "$pkgdir/usr/share/kbd/consolefonts/" out/*.psf.gz
}