blob: 85d474f5077f189e857092f2f111ddcc985c2823 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
|
set terminal epslatex size 3.417, 5.3
set output "fig_harmonic-susceptibilities.tex"
data4 = "data/harmonic-susceptibilities/order-4.dat"
data6 = "data/harmonic-susceptibilities/order-6.dat"
set palette defined (0 'blue', 0.33 'green', 0.66 'yellow', 1 'red')
stats data6 using "H"
set cbrange[STATS_min:STATS_max]
set logscale xycb
set nokey
set xrange [1:5000]
set yrange [0.01:10000]
unset colorbox
set multiplot layout 2,1 margins 0.15, 0.99, 0.225, 0.99 spacing 0,0.015
set size ratio 1 / 1.61803398875
unset xlabel
set ylabel '$\chi$' offset 3
set format x ''
plot data4 using "L":"X":"dX":"H" with yerrorbars pt 0 lw 2 palette,\
data4 using "L":"X":"H" with lines palette
set xlabel '$L$'
set colorbox horizontal user origin 0.15, 0.1 size 0.84, 0.03
set cblabel '(Top) $h_4$ or (bottom) $h_6$'
set cbtics format '$10^{%T}$'
set format x
plot data6 using "L":"X":"dX":"H" with yerrorbars pt 0 lw 2 palette,\
data6 using "L":"X":"H" with lines palette
|
