1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
|
# colors
cc1 = "#5e81b5"
cc2 = "#e19c24"
cc2l = "#f9ebd3"
cc3 = "#1a85ff"
cc4 = "#d41159"
Tc = 17.26
a1 = 71.1212
b1 = 0.0104105
c1 = 0.00378087
d1 = 6.2662
C10(T) = a1 - b1 * T
C1(T) = C10(T) / (1 + d1 / (1 + c1 * abs(T - Tc)) / C10(T))
a2 = 144.345
b2 = 0.019492
c2 = 120.462
C20(T) = a2 - b2 * T**2 / (c2 + T)
set terminal epslatex size 8.68cm, 6.7cm standalone header \
'\usepackage{xcolor}\definecolor{mathc3}{HTML}{1a85ff}\definecolor{mathc4}{HTML}{d41159}'
set output "fig-stiffnesses.tex"
set multiplot layout 2, 2 margins 0.1, 0.88, 0.125, 0.99 spacing 0.01, 0.01
set nokey
set mxtics 2
set mx2tics 2
set mytics 2
set my2tics 2
set format y '\tiny $%1.f$'
set format y2 '\tiny $%.1f$'
set format x '\tiny $%.0f$'
#set format x2 '\tiny $%.0f$'
set format x2 ''
set style rect back fc rgb cc2l
set object 1 rect from 0,0 to Tc,200
set border lw 2 front
set tics front
set arrow 1 from Tc,graph 0 to Tc,graph 1 nohead lw 5 lc rgb cc2
unset xtics
set x2tics 50, 50, 250 offset 0,-0.5 mirror
#set x2label '\tiny $T / \mathrm K$' offset 0,-1.0
set xrange [0:300]
set title '(a)' offset 5,-2.7
set ylabel '\scriptsize $C_{\mathrm{B_{2\mathrm g}}} / \mathrm{GPa}$' offset 3.5
set yrange [140:145]
set ytics 141,1,144 offset 0.5 mirror
plot "data/c66.dat" using 1:(100 * $2) with lines lw 3 lc rgb cc3, \
C20(x) dt 3 lw 4 lc rgb cc4
set title '(b)' offset 5,-2.7
unset ylabel
set y2label '\scriptsize $C_{\mathrm{B_{1\mathrm g}}} / \mathrm{GPa}$' offset -5 rotate by -90
set yrange [65.05:65.7]
set y2tics 62.1,0.1,65.6 offset -0.5 mirror
plot "data/c11mc12.dat" using 1:(100 * $2) with lines lw 3 lc rgb cc3, \
C1(x) dt 3 lw 4 lc rgb cc4
unset x2label
unset x2tics
set title '(c)' offset 5,-2.7
set xlabel '\scriptsize $T / \mathrm K$\\~' offset 0,0.78
set xtics 50, 50, 250 offset 0,0.5 mirror
unset y2tics
set ytics 63,1,72
unset y2label
set ylabel '\scriptsize $\textcolor{mathc3}{C_{\mathrm{B_{1\mathrm g}}}},\textcolor{mathc4}{C_{\mathrm{B_{1\mathrm g}}}^0} / \mathrm{GPa}$' offset 3
set yrange [64.5:71.5]
plot "data/c11mc12.dat" using 1:(100 * $2) with lines lw 3 lc rgb cc3, \
C10(x) dt 3 lw 4 lc rgb cc4
set ylabel ''
set y2label '\scriptsize $[C^0(C^0/C - 1)]^{-1} / \mathrm{GPa}^{-1}$' offset -5.5 rotate by -90
set title '(d)' offset 5,-2.7
set format y2 '\tiny $%0.2f$'
set format y '\tiny $%0.2f$'
set yrange [0.12:0.38]
set y2tics 0.15,0.05,0.39 offset -0.7 mirror
plot "data/c11mc12.dat" using 1:(1 / (C10($1)*(C10($1) / (100 * $2) - 1))) with lines lw 3 lc rgb cc3, \
1/(C10(x) * (C10(x) / C1(x) - 1)) dt 3 lw 4 lc rgb cc4
|
