1 files changed, 159 insertions, 0 deletions
diff --git a/figs/fig_cluster-scaling.gplot b/figs/fig_cluster-scaling.gplot
new file mode 100644
index 0000000..d22be31
--- /dev/null
+++ b/figs/fig_cluster-scaling.gplot
@@ -0,0 +1,159 @@
+
+# data and constants, sorted by column
+
+isingRange = "[0.0000005:5000000]"
+
+dataIsing2D = "data/correlation-times/ising-2d.dat"
+betaIsing2D = 1.0 / 8.0
+nuIsing2D = 1.0
+deltaIsing2D = 15.0
+gammaIsing2D = 7.0 / 4.0
+
+dataIsing3D = "data/correlation-times/ising-3d.dat"
+betaIsing3D = 0.326419
+nuIsing3D = 0.629971
+deltaIsing3D = 4.78984
+gammaIsing3D = 1.237075
+
+pottsRange="[0.000001:5000000]"
+
+data3Potts2D = "data/correlation-times/potts-3.dat"
+beta3Potts2D = 1.0 / 9.0
+nu3Potts2D = 5.0 / 6.0
+delta3Potts2D = 14.0
+gamma3Potts2D = 13.0 / 9.0
+
+data4Potts2D = "data/correlation-times/potts-4.dat"
+beta4Potts2D = 1.0 / 12.0
+nu4Potts2D = 2.0 / 3.0
+delta4Potts2D = 15.0
+gamma4Potts2D = 7.0 / 6.0
+
+vectorRange="[0.000001:10000000]"
+
+data2Vector3D = "data/correlation-times/planar-pert.dat"
+beta2Vector3D = 0.3470
+nu2Vector3D = 0.6703
+delta2Vector3D = 4.79539
+gamma2Vector3D = 1.3169
+
+data3Vector3D = "data/correlation-times/heisenberg-pert.dat"
+beta3Vector3D = 0.3662
+nu3Vector3D = 0.7073
+delta3Vector3D = 4.79465
+gamma3Vector3D = 1.3895
+
+# define colors
+
+cc1 = "#5e81b5"
+cc2 = "#e19c24"
+cc3 = "#8fb032"
+cc4 = "#eb6235"
+cc5 = "#8778b3"
+cc6 = "#c56e1a"
+cc7 = "#5d9ec7"
+cc8 = "#ffbf00"
+
+set palette model RGB defined ( 4 cc1, 8 cc2, 16 cc3, 32 cc4, 64 cc5, 128 cc6, 256 cc7 , 512 cc8 )
+set cbrange [4:512]
+
+# global plotting settings
+
+set terminal epslatex size 6.834, 3.3
+set output "fig_cluster-scaling.tex"
+
+set multiplot layout 2,3 margins 0.05, 0.995, 0.15, 0.9 spacing 0.05, 0.015
+set size ratio 1 / 1.61803398875
+set key autotitle columnhead
+unset colorbox
+set nokey
+set logscale xy
+
+scaledylabel = '"$\\avg{s_{\\text{\\sc 1c}}}L^{-D\\gamma/\\nu}$" offset 2,0'
+
+# plotting the first row
+set format x ""
+unset xlabel
+set ylabel @scaledylabel
+
+# ploting Ising 2D
+set xrange @isingRange
+set yrange [0.8:6]
+
+set title '\twodee Ising' offset -6.5,-2.5
+
+plot dataIsing2D using (column("H")/column("T") * exp(log(column("L")) * betaIsing2D * deltaIsing2D / nuIsing2D)):(column("S") * exp(-log(column("L")) * (gammaIsing2D / nuIsing2D))):(column("dS") * exp(-log(column("L")) * (gammaIsing2D / nuIsing2D))):1 with yerrorbars pt 0 lw 2 palette,\
+  dataIsing2D using (column("H")/column("T") * exp(log(column("L")) * betaIsing2D * deltaIsing2D / nuIsing2D)):(column("S") * exp(-log(column("L")) * (gammaIsing2D / nuIsing2D))):1 with lines palette,\
+  1.4 * exp(log(x) * 2 / deltaIsing2D) with lines lc rgb "black"
+ 
+unset ylabel
+
+# plotting 3 Potts 2D
+set xrange @pottsRange
+set yrange [0.9:6]
+
+set title '\twodee 3-State Potts' offset -4,-2.5
+
+set key above center vertical maxrows 1
+
+plot data3Potts2D using (column("H")/column("T") * exp(log(column("L")) * beta3Potts2D * delta3Potts2D / nu3Potts2D)):(column("S") * exp(-log(column("L")) * (gamma3Potts2D / nu3Potts2D))):(column("dS") * exp(-log(column("L")) * (gamma3Potts2D / nu3Potts2D))):1 with yerrorbars pt 0 lw 2 palette notitle,\
+  data3Potts2D using (column("H")/column("T") * exp(log(column("L")) * beta3Potts2D * delta3Potts2D / nu3Potts2D)):(column("S") * exp(-log(column("L")) * (gamma3Potts2D / nu3Potts2D))):1 with lines palette notitle,\
+  1.4 * exp(log(x) * 2 / delta3Potts2D) with lines lc rgb "black",\
+  NaN with lines lc rgb cc1 title "4",\
+  NaN with lines lc rgb cc2 title "8",\
+  NaN with lines lc rgb cc3 title "16",\
+  NaN with lines lc rgb cc4 title "32",\
+  NaN with lines lc rgb cc5 title "64",\
+  NaN with lines lc rgb cc6 title "128",\
+  NaN with lines lc rgb cc7 title "256",\
+  NaN with lines lc rgb cc8 title "512"
+
+unset key
+
+# plotting 2 Vector 3D
+set xrange @vectorRange
+set yrange [0.2:80]
+
+set title '\threedee O(2)' offset -6.5,-2.5
+
+plot data2Vector3D using (column("H")/column("T") * exp(log(column("L")) * beta2Vector3D * delta2Vector3D / nu2Vector3D)):(column("S") * exp(-log(column("L")) * (gamma2Vector3D / nu2Vector3D))):(column("dS") * exp(-log(column("L")) * (gamma2Vector3D / nu2Vector3D))):1 with yerrorbars pt 0 lw 2 palette,\
+  data2Vector3D using (column("H")/column("T") * exp(log(column("L")) * beta2Vector3D * delta2Vector3D / nu2Vector3D)):(column("S") * exp(-log(column("L")) * (gamma2Vector3D / nu2Vector3D))):1 with lines palette,\
+  1 * exp(log(x) * 2 / delta2Vector3D) with lines lc rgb "black"
+
+# plotting the second row
+set format x '$10^{%T}$'
+set xlabel '$hL^{\beta\delta/\nu}$'
+set ylabel @scaledylabel
+
+# plotting Ising 3D
+set xrange @isingRange
+set yrange [0.5:200]
+
+set title '\threedee Ising' offset -6.5,-2.5
+
+plot dataIsing3D using (column("H")/column("T") * exp(log(column("L")) * betaIsing3D * deltaIsing3D / nuIsing3D)):(column("S") * exp(-log(column("L")) * (gammaIsing3D / nuIsing3D))):(column("dS") * exp(-log(column("L")) * (gammaIsing3D / nuIsing3D))):1 with yerrorbars pt 0 lw 2 palette,\
+  dataIsing3D using (column("H")/column("T") * exp(log(column("L")) * betaIsing3D * deltaIsing3D / nuIsing3D)):(column("S") * exp(-log(column("L")) * (gammaIsing3D / nuIsing3D))):1 with lines palette,\
+  4 * exp(log(x) * 2 / deltaIsing3D) with lines lc rgb "black"
+
+unset ylabel
+
+# plotting 4 Potts 2D
+set xrange @pottsRange
+set yrange [0.8:6]
+
+set title '\twodee 4-State Potts' offset -4,-2.5
+
+plot data4Potts2D using (column("H")/column("T") * exp(log(column("L")) * beta4Potts2D * delta4Potts2D / nu4Potts2D)):(column("S") * exp(-log(column("L")) * (gamma4Potts2D / nu4Potts2D))):(column("dS") * exp(-log(column("L")) * (gamma4Potts2D / nu4Potts2D))):1 with yerrorbars pt 0 lw 2 palette,\
+  data4Potts2D using (column("H")/column("T") * exp(log(column("L")) * beta4Potts2D * delta4Potts2D / nu4Potts2D)):(column("S") * exp(-log(column("L")) * (gamma4Potts2D / nu4Potts2D))):1 with lines palette,\
+  1.4 * exp(log(x) * 2 / delta4Potts2D) with lines lc rgb "black"
+
+# plotting 3 Vector 3D
+set xrange @vectorRange
+set yrange [0.3:100]
+
+set title '\threedee O(3)' offset -6.5,-2.5
+
+plot data3Vector3D using (column("H")/column("T") * exp(log(column("L")) * beta3Vector3D * delta3Vector3D / nu3Vector3D)):(column("S") * exp(-log(column("L")) * (gamma3Vector3D / nu3Vector3D))):(column("dS") * exp(-log(column("L")) * (gamma3Vector3D / nu3Vector3D))):1 with yerrorbars pt 0 lw 2 palette,\
+  data3Vector3D using (column("H")/column("T") * exp(log(column("L")) * beta3Vector3D * delta3Vector3D / nu3Vector3D)):(column("S") * exp(-log(column("L")) * (gamma3Vector3D / nu3Vector3D))):1 with lines palette,\
+  1 * exp(log(x) * 2 / delta3Vector3D) with lines lc rgb "black"
+