blob: 13d67f1c547a5ba2d8043901708c350e5a4c7708 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
# U-Boot: Pinebook, based on Pine64 PKGBUILD
# Maintainer: Dan Johansen <strit@manjaro.org>
# Contributor: Kevin Mihelich <kevin@archlinuxarm.org>
pkgname=uboot-pinebook
pkgver=2020.10
pkgrel=1
_tfaver=2.3
pkgdesc="U-Boot for Pinebook"
arch=('aarch64')
url='http://www.denx.de/wiki/U-Boot/WebHome'
license=('GPL')
makedepends=('bc' 'git' 'python' 'swig' 'dtc')
provides=('uboot')
conflicts=('uboot')
install=${pkgname}.install
source=("ftp://ftp.denx.de/pub/u-boot/u-boot-${pkgver/rc/-rc}.tar.bz2"
"https://git.trustedfirmware.org/TF-A/trusted-firmware-a.git/snapshot/trusted-firmware-a-$_tfaver.tar.gz")
md5sums=('14656f08aa73a8dbbde2424fe78bbe3b'
'628a32a3c3b3f0c567d1ea6ee5582807')
build() {
unset CFLAGS CXXFLAGS CPPFLAGS LDFLAGS
cd trusted-firmware-a-$_tfaver
make PLAT=sun50i_a64 DEBUG=1 bl31
cp build/sun50i_a64/debug/bl31.bin ../u-boot-${pkgver/rc/-rc}
cd ../u-boot-${pkgver/rc/-rc}
make distclean
make pinebook_defconfig
echo 'CONFIG_IDENT_STRING=" Manjaro ARM"' >> .config
make EXTRAVERSION=-${pkgrel}
cat spl/sunxi-spl.bin u-boot.itb > u-boot-sunxi-with-spl-pinebook.bin
}
package() {
cd u-boot-${pkgver/rc/-rc}
mkdir -p "${pkgdir}"/boot/extlinux
cp u-boot-sunxi-with-spl-pinebook.bin "${pkgdir}"/boot
}
|
