summaryrefslogtreecommitdiff
path: root/PKGBUILD
blob: 8a5a77cf9d6e88da711354d6fc4d30756f0f9b01 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
# U-Boot: Pine64
# Maintainer: Dan Johansen <strit@manjaro.org>
# Contributor: Kevin Mihelich <kevin@archlinuxarm.org>

pkgname=uboot-pinebook
pkgver=v2019.01.rc3.r35.g64abfc9b6b
pkgrel=2
pkgdesc="U-Boot for Pine64"
arch=('aarch64')
url='http://www.denx.de/wiki/U-Boot/WebHome'
license=('GPL')
makedepends=('bc' 'git' 'python' 'swig' 'dtc')
backup=('boot/extlinux/extlinux.conf')
install=${pkgname}.install
source=('git+https://github.com/u-boot/u-boot.git#commit=64abfc9b6bb3'
        'git+https://github.com/ARM-software/arm-trusted-firmware.git#commit=63b9b5425f15'
        '0001-ATF-set-fno-stack-protector.patch'
        'extlinux.conf')
md5sums=('SKIP'
         'SKIP'
         '3213c96ce0713249719dc73d58395620'
         '96aebf8a7cca044bb2c765ba8812299b')

pkgver() {
  cd u-boot
  git describe --long | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

prepare() {
  cd u-boot

  cd ../arm-trusted-firmware
  git apply ../0001-ATF-set-fno-stack-protector.patch
}

build() {
  unset CFLAGS CXXFLAGS CPPFLAGS LDFLAGS

  cd arm-trusted-firmware

  make PLAT=sun50i_a64 DEBUG=1 bl31
  cp build/sun50i_a64/debug/bl31.bin ../u-boot

  cd ../u-boot

  make distclean
  make pinebook_defconfig
  echo 'CONFIG_IDENT_STRING=" Manjaro ARM"' >> .config
  make EXTRAVERSION=-${pkgrel}
  cat spl/sunxi-spl.bin u-boot.itb > u-boot-sunxi-with-spl-pinebook.bin
}

package() {
  cd u-boot

  mkdir -p "${pkgdir}"/boot/extlinux

  cp u-boot-sunxi-with-spl-pinebook.bin "${pkgdir}"/boot
  cp "${srcdir}"/extlinux.conf "${pkgdir}"/boot/extlinux/
}